BBO Discussion Forums: Bidding Table and Dealer Source - BBO Discussion Forums

Jump to content

Page 1 of 1

Bidding Table and Dealer Source Get BBO to deal specific hands to practise

#1 User is offline   fbear 

  • PipPip
  • Group: Members
  • Posts: 15
  • Joined: 2013-September-13

Posted 2014-December-02, 06:10

I have been keeping a list of 'Dealer Source' criteria when using the BBO 'Bidding Table' to practise with my partner. Anyone unfamiliar with this facility should give it a try. Personally I think this must be one of the most powerful Bridge tools on the Internet.

Get BBO to deal hands for you that satisfy a particular criteria - shape and values, then another and another and bid them all until you're happy your system copes.

My 'Dealer Source code' could be improved on, I'm sure, but it works - see below.

If you find it useful, that's good. But the gratitude must go to BBO and the facilities provided - generously free and amazingly powerful.



BRIDGE BASE ONLINE – Hand Generating instructions

The following instructions detail how to get BBO to deal hands for you to practise with. You can use the ‘computer code’ like instructions to tell BBO what kinds of hands you want, but it isn’t very hard once you have tried it yourself. This document also contains many examples of such code so you can cut and paste it or adapt it for your own needs. The code examples aren’t perfect and I’ve been learning myself as I’ve been going along, but they are a start point.

I’ve given instructions on how to setup a bidding table which is a wonderfully powerful way for you and your partner to practise your system and to get BBO to deal hands for a particular area.

Using the following webpage and pasting the syntax into it will generate a number of deals that can be analysed.

http://www.bridgebas...aler/dealer.php

Alternatively with a BBO account, you can follow these instructions to setup a bidding table and get BBO to deal hands for you that fit a specific criteria.

Login to BBO
Click 'Start a table'
Click 'Start a Bidding table'
Under ‘Reserve Seats’ – if you have a partner who you want to practise with, enter their and your BBO account names into the North and South boxes. If you want to practise on your own, then leave them blank.
Click 'Start Table'.
On the table, click either the North or South seat to sit (unless you reserved a seat on the previous screen), then click on 'Robot' for the other seats - note if you want the E-W pair to pass don't bother clicking on 'Robot' for them just select it for your North or South partner if bidding on your own.
Click 'Deal Source' under the playing table window.
On the 'General' tab, uncheck the seats you don't want to open the bidding if required - e.g. if you want to practice 1NT openings set North or South as the only player to open the bidding
Click on the 'Advanced' tab
Click in the checkbox for the 'Use this input for the Dealer program'
Then cut and paste the relevant code from this document into the open space below or enter your own.

e.g. Use the following to force a 1NT opening for North and then some kind of minor suit holding for South. It is fairly self explanatory, but the keyword 'shape' means north can have any of the exact shapes listed with 'hcp' high card points in the range 15-17. And South's shape can be any of those listed where x can be any number and the order is SHDC.

(
shape(north, any 5332 + any 4432 + any 4333)&&
hcp(north)>=15&&hcp(north)<=17&&shape(south, 22xx +31xx + 13xx + xx5x + xxx5) &&hcp(south)>8
)

Click 'Close'
Click 'Redeal' on the table window to get a new deal satisfying the dealing criteria

Pete Foster (Nov 2014)


Dealer Source criteria
----------------------

MINOR SUITS


To get an opening 1C bid (NB most of the hands will provide a 1NT 12-14 opening as it is far more common than the 18-19 hand).

(clubs(north)>=1&&diamonds(north)<=3&&hearts(north)<=4&&spades(north)<=4&&((hcp(north)>=12&&hcp(north)<=14)||(hcp(north)>=18&&hcp(north)<=19)))||
(clubs(north)>=4&&diamonds(north)<clubs(north)&&hearts(north)<clubs(north)&&spades(north)<clubs(north)&&hcp(north)>=12&&!(hcp(north)>=15||hcp(north)<=17))

To get an opening 1C bid that is NOT a weak 12-14 1NT

hcp(north)>11&&
((!shape(north, any 4333 + any 4432 + any 5332)&&
clubs(north)>=1&&diamonds(north)<=4&&hearts(north)<=4&&spades(north)<=4)||
(shape(north, any 4333 + any 4432 + any 5332)&&hcp(north)>17&&hcp(north)<20))

To get an opening 1C bid and a 4-4 major suit fit.

(clubs(north)>=1&&diamonds(north)<=3&&hearts(north)<=4&&spades(north)<=4&&((hcp(north)>=12&&hcp(north)<=14)||(hcp(north)>=18&&hcp(north)<=19)))||
(clubs(north)>=4&&diamonds(north)<clubs(north)&&hearts(north)<clubs(north)&&spades(north)<clubs(north)&&hcp(north)>=12&&!(hcp(north)>=15||hcp(north)<=17))&&
((spades(south)>=4&&spades(north)==4)||(hearts(south)>=4&&hearts(north)==4))&&hcp(south)>=6

To get an opening 1C bid and a 4-4 major suit fit and opener is 18-19
(clubs(north)>=1&&diamonds(north)<=3&&hearts(north)<=4&&spades(north)<=4&&(hcp(north)>=18&&hcp(north)<=19))&&
((spades(south)>=4&&spades(north)==4)||(hearts(south)>=4&&hearts(north)==4))&&hcp(south)>=6

To get an opening 1C bid and inverted 2C response.

(clubs(south)>=4&&hearts(south)<=3&&spades(south)<=3&&hcp(south)>=10)&&(clubs(north)>=1&&diamonds(north)<=3&&hearts(north)<=4&&spades(north)<=4&&((hcp(north)>=12&&hcp(north)<=14)||(hcp(north)>=18&&hcp(north)<=19)))

To get an opening 1C bid and responder hold 4+ clubs.
(hcp(north)+hcp(south)>=22)&&(clubs(south)>=4&&hearts(south)<=3&&spades(south)<=3&&diamonds(south)<=3)&&(clubs(north)>=1&&diamonds(north)<=3&&hearts(north)<=4&&spades(north)<=4&&((hcp(north)>=12&&hcp(north)<=14)||(hcp(north)>=18&&hcp(north)<=19)))

To get a natural opening 1C bid that isn't a strong NT:-

(clubs(north)>=4&&hearts(north)<=3&&spades(north)<=3&&diamonds(north)<=3&&hcp(north)>=12&&hcp(north)<=19&&!(hcp(north)>=15&&hcp(north)<=17))


INVERTED MINOR


To get an opening 1m and inverted response:-

(clubs(south)>=4&&diamonds(south)<=3&&hearts(south)<=3&&spades(south)<=3&&hcp(south)>=10)&&
(clubs(north)>=1&&diamonds(north)<=4&&hearts(north)<=4&&spades(north)<=4&&
((hcp(north)>=12&&hcp(north)<=14)||(hcp(north)>=18&&hcp(north)<=19)))
||
(diamonds(south)>=4&&hearts(south)<=3&&spades(south)<=3&&clubs(south)<=4&&hcp(south)>=10)&&
(diamonds(north)>=4&&clubs(north)<=3&&hearts(north)<=4&&spades(north)<=4&&((hcp(north)>=12&&hcp(north)<=14)||(hcp(north)>=18&&hcp(north)<=19)))


MAJOR SUITS


To get an opening 1M bid:-

(hearts(north)>=5||spades(north)>=5)&&hcp(north)>=12&&hcp(north)<=19&&!(shape(north, any 5332)&&hcp(north)>=15&&hcp(north)<=17)

To get a responding hand to 1M with 7+ points:-

(hearts(north)>=5||spades(north)>=5)&&hcp(north)>=12&&hcp(north)<=19&&!(shape(north, any 5332)&&hcp(north)>=15&&hcp(north)<=17)&&hcp(south)>=7

To get an opening 1M and responding hand with 10-12 HCP:-

(hearts(north)>=5||spades(north)>=5)&&hcp(north)>=12&&hcp(north)<=19&&!(shape(north, any 5332)&&hcp(north)>=15&&hcp(north)<=17)&&(hcp(south)>=10&&hcp(south)<=12)

To get a 1NT responding hand to 1M :-

((hearts(north)>=5&&hearts(south)<3&&spades(south)<4)||(spades(north)>=5&&spades(south)<3))&&hcp(north)>=12&&hcp(north)<=19&&!(shape(north, any 5332)&&hcp(north)>=15&&hcp(north)<=17)&&hcp(south)<13&&hcp(south)>4

To get a responding hand to 1M with 3+ card support and 4+ HCP:-

((hearts(north)>=5&&hearts(south)>=3)||(spades(north)>=5&&spades(south)>=3))&&hcp(north)>=12&&hcp(north)<=19&&!(shape(north, any 5332)&&hcp(north)>=15&&hcp(north)<=17)&&hcp(south)>4

To get a responding hand to 1M with 3+ card support and 2+ HCP with intervention:-

((hearts(north)>=5&&hearts(south)>=3)||(spades(north)>=5&&spades(south)>=3))&&hcp(north)>=12&&hcp(north)<=19&&!(shape(north, any 5332)&&hcp(north)>=15&&hcp(north)<=17)&&hcp(south)>=2&&hcp(east)>=13&&shape(east, any 5xxx + any 4441)


To get a 5 card Major with shape 5422:-

hcp(north)>=12&&hcp(north)<=19&&shape(north, 5422 + 4522 + 5242 +5224 + 2542 + 2524)




1NT OPENING


To get an opening 1NT:-

strongNT =
(
shape(north, any 5332 + any 4432 + any 4333)&&
hcp(north)>=15&&hcp(north)<=17
)
condition strongNT

To get an opening 1NT with a 5 card Major with shape 5422 or 5332:-

hcp(north)>=15&&hcp(north)<=17 &&
(
(shape(north, 5422 + 4522) && hcp(north, clubs)>4 && hcp(north, diamonds)>4)||
(shape(north, 5242) && hcp(north, clubs)>4 && hcp(north, hearts)>4)||
(shape(north, 5224) && hcp(north, hearts)>4 && hcp(north, diamonds)>4)||
(shape(north, 2542) && hcp(north, clubs)>4 && hcp(north, spades)>4)||
(shape(north, 2524) && hcp(north, spades)>4 && hcp(north, diamonds)>4)||
(shape(north, 5332 + 5233 + 5323 + 3532 + 3523 + 2533))
)

To get an opening 1NT with the balance of points:-

condition strongNT&&hcp(south)>6

To get an opening 1NT with the balance of points and responder no more than 4 cards in majors:-

condition strongNT&&(shape(south,22xx + 31xx + 13xx + 21xx + 12xx + 30xx + 03xx))&&hcp(south)>6

To get an opening 1NT with the balance of points and responder with a 5+ card minor:-

condition strongNT&&shape(south, 22xx +31xx + 13xx + xx5x + xxx5) &&hcp(south)>6

To get an opening 1NT with the balance of points and responder with any 5 card suit or 4441:-

condition strongNT&&shape(south, any 5xxx + any 4441) &&hcp(south)>6

To get an opening 1NT with a 2 suiter responding hand:-

condition strongNT&&shape(south, any 54xx + any 55xx + any 64xx)&&hcp(south)>=6


To get an opening 1NT with a 2S, 3x or 2NT response:-
condition strongNT&&
( (
shape(south, any 4333 + any 4432)&&
hcp(south)>15
)||
(
shape(south, xx6x + xxx6 + xx7x + xxx7)&&
hcp(south)<7
)||
(
hcp(south)<9&&
((shape(south, xxx6)&&hcp(south,clubs)>4&&hascard(south,TC))||
(shape(south, xx6x)&&hcp(south,diamonds)>4&&hascard(south,TD))||
(shape(south, x6xx)&&hcp(south,hearts)>4&&hascard(south,TH))||
(shape(south, 6xxx)&&hcp(south,spades)>4&&hascard(south,TS)))
)
)


To get an opening 1NT with the balance of points and a Robot intervention:-

condition strongNT&&
hcp(east)>12&&shape(east, any 6xxx + any 5440 + any 55xx)&&
(hcp(north)+hcp(south)>=21)





REVERSES


To get a reversing shape where the responding hand has GF values:-

(hcp(south)>=12)&&
( (hcp(north)>=16&&hcp(north)<=21) || (hcp(north)>=11&&hcp(north)<=15) ) &&
(
(hearts(north)>=5&&spades(north)==4&&(clubs(south)>=5||diamonds(south)>=5) )||
(diamonds(north)>=5&&hearts(north)==4&&spades(south)>=4)||
(clubs(north)>=5&&diamonds(north)==4&&(hearts(south)>=4||spades(south)>=4))||
(clubs(north)>=5&&hearts(north)==4&&spades(south)>=4)
)


To get a reversing shape where the responding hand has a 2/1 GF response:-

(hcp(south)>=13)&&
( (hcp(north)>=16&&hcp(north)<=21) || (hcp(north)>=11&&hcp(north)<=15) ) &&
(
(hearts(north)>=5&&spades(north)==4&&(clubs(south)>=5||diamonds(south)>=5) )||
(diamonds(north)>=5&&hearts(north)==4&&clubs(south)>=5)||
(diamonds(north)>=5&&spades(north)==4&&clubs(south)>=5)
)


NON-FORCING FREE-BIDS

To get an opening 1C bid and 1M overcall and responder have 5+ cards in a displaced suit with 6+ HCP

(clubs(north)>=1&&diamonds(north)<=3&&hearts(north)<=4&&spades(north)<=4&&((hcp(north)>=12&&hcp(north)<=14)||(hcp(north)>=18&&hcp(north)<=19)))
&&
(
(hearts(east)>=5&&diamonds(south)>=5)||
(spades(east)>=5&&(diamonds(south)>=5||hearts(south)>=5))
)
&&hcp(east)>=12
&&hcp(south)>=6


4441 HANDS

To get a 4441 hand:-

(shape(north, 4441)||shape(north, 4414)||shape(north, 4144)||shape(north, 1444))&&
hcp(north)>=12&&hcp(south)>=6


TWO OVER ONE GAME FORCE


To get a 5 card major opening & a responding hand with a 2/1 GF response:-

(hcp(south)>=13)&&
( (hcp(north)>=16&&hcp(north)<=21) || (hcp(north)>=11&&hcp(north)<=14) ) &&
(
(hearts(north)>=5&&(clubs(south)>=5||diamonds(south)>=5) )||
(spades(north)>=5&&(clubs(south)>=5||diamonds(south)>=5||hearts(south)>=5) )
)



TWO SUITED OVERCALLS

To get a Michaels Cue bid or Unusual 2NT overcall (NB will also get ‘extremes’ e.g. (1C)-? D+S)

(
(hearts(west)>=5&&shape(north, 5x5x+5xx5+xx55))||
(spades(west)>=5&&shape(north, x55x+x5x5+xx55))||
(clubs(west)>=4&&hearts(west)<=4&&spades(west)<=4&&shape(north, 55xx+5x5x+x55x))||
(diamonds(west)>=4&&hearts(west)<=4&&spades(west)<=4&&shape(north, 55xx+5xx5+x5x5))
)&&
hcp(west)>=12&&hcp(west)<=19&&!(shape(west, any 5332 + any 4432 + any 4333)&&hcp(west)>=15&&hcp(west)<=17)
&&hcp(north)>=6



WIDE RANGE 1NT RESPONSE

To get a 1D/M opening with 1NT response

(
(hearts(north)>=5&&shape(south, 3244 + 3253 + 3235 + 31xx + 21xx))||
(spades(north)>=5&&shape(south, 2344 + 2353 + 2335 + 1xxx + 2xxx))||
((diamonds(north)>=5||shape(north, 3343))&&shape(south, 3235 + 2335 + 3325))
)&&
hcp(north)>=12&&hcp(north)<=19&&
!(shape(north, any 5332)&&hcp(north)>=15&&hcp(north)<=17)&&
hcp(south)>=6&&hcp(south)<=11


OPENING 2C


To get a 2C opening, either less than 5 loser hand & 19+ HCP or any 23+ HCP with specific distributional response

(
(
loser(south)<5&&hcp(south)>19
)||
hcp(south)>=23
)&&
shape(north, any 6xxx + any 7xxx)


To get distributional hands that qualify for a 2C opening – i.e. satisfy the ‘Rule of 25’ but are less than 22 HCP

loser(south)<5&&hcp(south)>16&&hcp(south)<22&&shape(south, any 6xxx + any 7xxx + any 55xx)


To get a 2C opening, either less than 5 loser hand & 19+ HCP or any 23+ HCP with a potential overcall (NB BBO robots don’t overcall, so you need to rebid considering the auction if they had

((loser(south)<5&&hcp(south)>19)||hcp(south)>=23)&&
(
(shape(east,xxx6)&&hcp(east,clubs)>=5)||
(shape(east,xx6x)&&hcp(east,diamonds)>=5)||
(shape(east,x6xx)&&hcp(east,hearts)>=5)||
(shape(east,6xxx)&&hcp(east,spades)>=5)
)


OPENING 2D – EKREN


To get an Ekren opening with a responding 15 HCP opposite.

(
hearts(north)>=4&&spades(north)>=4&&
hcp(north)>=5&&hcp(north)<=9
)&&
hcp(south)>=15


OPENING 2D/2M – ‘MULTI-STYLE’


To get an opening 2D ‘weak’ Weak 2M (showing 5+ cards + another suit or 6 card suit <8 HCP) OR opening 2M ‘intermediate’ 2M (showing 8-11 HCP with a 6 card suit)

(
(shape(north, 6xxx + x6xx)&&hcp(north)<12)||
(shape(north, 55xx + 54xx + 45xx + 5x4x + 5xx4 + x54x + x5x4 + 5x5x + 5xx5 + x55x + x5x5)&&hcp(north)<8)
)


OPENING 2NT:-

To get an opening 2NT

opening2NT =
(
shape(north, any 5332 + any 4432 + any 4333)&&
hcp(north)>=20&&hcp(north)<=22
)
condition opening2NT

To get an opening 2NT and responder has both minors

condition opening2NT&&
(
(shape(south, xx54 + xx45 + xx55 + xx65 + xx56)&&hcp(south)>3)||
(shape(south, 2344 + 3244)&&hcp(south)>10)
)

To get an opening 1NT or 2NT with a 2/3C, 2/3S or 2N response:-

(
shape(north, any 5332 + any 4432 + any 4333)&&
((hcp(north)>=15&&hcp(north)<=17)||(hcp(north)>=20&&hcp(north)<=22))
)&&
(
(
shape(south, any 4333 + any 4432 + any 4441)&&
hcp(south)>7
)||
(
shape(south, xx6x + xxx6 + xx7x + xxx7)&&
hcp(south)<8
)||
(
shape(south, xx54 + xx45 + xx55 + xx65 + xx56)&&
hcp(south)>7
)
)


To get a 1NT or 2NT opening with balanced hands and minor suit 2 suiters :

shape(north, any 5332 + any 4432 + any 4333)&&
(
hcp(north)>=20&&hcp(north)<=22&&
(
(shape(south, any 4333 + any 2344)&&hcp(south)>11)||
(shape(south, 2344 + 3244 + 1354 + 3154 + 2254)&&hcp(south)>10)
)
)||
(
hcp(north)>=15&&hcp(north)<=17&&
(
(shape(south, any 4333 + any 2344)&&hcp(south)>16)||
(shape(south, 2344 + 3244 + 1354 + 3154 + 2254)&&hcp(south)>15)
)
)





PRE-EMPTIVE OPENINGS


To get a Weak 2M opening

hcp(south)>3&&hcp(south)<=9&&
(
(shape(south,x6xx)&&hcp(south, hearts)>2)||(shape(south,6xxx)&&hcp(south, spades)>2)
)

To get a Weak 2M or 2 suited opening

hcp(south)>4&&hcp(south)<=9&&
(
((shape(south,x6xx)&&hcp(south, hearts)>2)||(shape(south,6xxx)&&hcp(south, spades)>2))||
(shape(south, any 55xx)||shape(south, any 54xx)||shape(south, 44xx))
)

To get a Weak 2 opening with a takeout double and Lebensohl opposite double

(
hcp(east)>5&&hcp(east)<=9&&
(
((shape(east,xx6x)&&spades(east)<4&&hearts(east)<4)&&hcp(east,diamonds)>4&&shape(south, 4414+4504+5404+4405+4513+5413+3415+4315))||
(shape(east,26xx)&&hcp(east,hearts)>4&&shape(south, 4144+5044+4054+4045+4153+4135+5143+5134))||
(shape(east,62xx)&&hcp(east,spades)>4&&shape(south, 1444+0544+0454+0445+1453+1435+1543+1534))
)&&
hcp(south)>13&&
shape(north, any 5xxx)
)

To get a Weak 2 opening with a Leaping Michaels overall

(
hcp(east)>5&&hcp(east)<=9&&
(
((shape(east,xx6x)&&spades(east)<4&&hearts(east)<4)&&hcp(east,diamonds)>4&&shape(south, 55xx+5xx5+x5x5+65xx+56xx+5xx6+6xx5+x5x6+x6x5))||
(shape(east,26xx)&&hcp(east,hearts)>4&&shape(south, 5x5x+5xx5+xx55+6x5x+5x6x+5xx6+6xx5+xx56+xx65))||
(shape(east,62xx)&&hcp(east,spades)>4&&shape(south, x55x+x5x5+xx55+x65x+x56x+x5x6+x6x5+xx56+xx65))
)&&
hcp(south)>17
)


To get a Weak 3 opening with a takeout double

(
hcp(east)>5&&hcp(east)<=9&&
(
((shape(east,xxx7)&&spades(east)<4&&hearts(east)<4)&&hcp(east,clubs)>4&&shape(south, 4441+4540+5440+4450+4531+5431+3451+4351))||
((shape(east,xx7x)&&spades(east)<4&&hearts(east)<4)&&hcp(east,diamonds)>4&&shape(south, 4414+4504+5404+4405+4513+5413+3415+4315))||
(shape(east,27xx)&&hcp(east,hearts)>4&&shape(south, 4144+5044+4054+4045+4153+4135+5143+5134))||
(shape(east,72xx)&&hcp(east,spades)>4&&shape(south, 1444+0544+0454+0445+1453+1435+1543+1534))
)&&
hcp(south)>13
)


To get a Weak 3 opening with a Non-Leaping Michaels overall

(
hcp(east)>5&&hcp(east)<=9&&
(
((shape(east,xxx7)&&spades(east)<4&&hearts(east)<4)&&hcp(east,clubs)>4&&shape(south, 55xx+5x5x+x55x+65xx+56xx+5x6x+6x5x+x56x+x65x))||
((shape(east,xx7x)&&spades(east)<4&&hearts(east)<4)&&hcp(east,diamonds)>4&&shape(south, 55xx+5xx5+x5x5+65xx+56xx+5xx6+6xx5+x5x6+x6x5))||
(shape(east,27xx)&&hcp(east,hearts)>4&&shape(south, 5x5x+5xx5+xx55+6x5x+5x6x+5xx6+6xx5+xx56+xx65))||
(shape(east,72xx)&&hcp(east,spades)>4&&shape(south, x55x+x5x5+xx55+x65x+x56x+x5x6+x6x5+xx56+xx65))
)&&
hcp(south)>17
)



To get BBO to deal specific cards and force an auction

predeal north SA83, HAT, DQJ9754, C74
predeal west SQT742, HKQJ6, DT, CQJ6
west1s = hcp(west)>10 && spades(west)>= 5
north3d = hcp(north)>6 && diamonds(north)>= 6
condition west1s && north3d

It would be nice if BBO forced West to open 1S and North overcall 3D, but the keywords do not refer to the bids, only to force the distributions set by the keyword criteria. In the above example therefore the west1s and north3d have no use since they have already been assigned their cards.

So, to get North to overcall 3D you have to sit in that seat and do it, then let the robots take the other polarities.


Other specific card holding conditions:-

aces(south) == 1 && kings(south) == 1 (also able to specify queens, jacks and tens)
clubs(south)==7 and hascard(south,AC) and hascard(south,KC) and hascard(south,QC)


You can get GIB to analyse a hand by using this as input to the Dealer Source:-

predeal north S63, HK52, DQJ7, CAK543
predeal south SA, HA874, DK53, CQT762
predeal east SJT9852, HJ63, DT2, CJ9
2

#2 User is offline   paulg 

  • PipPipPipPipPipPipPipPip
  • Group: Advanced Members
  • Posts: 5,048
  • Joined: 2003-April-26
  • Gender:Male
  • Location:Scottish Borders

Posted 2014-December-02, 06:22

As well as emphasising the need to restrict the opening hand on the General tab to the hand that you are providing opening constraints, I would recommend the checkbox for 'Randomly rotate generated deals 180 degrees' - this is a really useful feature: after the hands are generated, they will be rotated so that both partners are able to practise holding the specified opening hand.
The Beer Card

I don't work for BBO and any advice is based on my BBO experience over the decades
0

#3 User is offline   fbear 

  • PipPip
  • Group: Members
  • Posts: 15
  • Joined: 2013-September-13

Posted 2014-December-02, 08:31

View Postpaulg, on 2014-December-02, 06:22, said:

As well as emphasising the need to restrict the opening hand on the General tab to the hand that you are providing opening constraints, I would recommend the checkbox for 'Randomly rotate generated deals 180 degrees' - this is a really useful feature: after the hands are generated, they will be rotated so that both partners are able to practise holding the specified opening hand.


Yes - thanks for that, a powerful option when using the facility with a partner.
0

#4 User is offline   miko 

  • Pip
  • Group: Members
  • Posts: 9
  • Joined: 2005-September-02
  • Gender:Male
  • Location:Just south of Charlotte NC in SC
  • Interests:Yoga

Posted 2016-March-01, 13:47

View Postpaulg, on 2014-December-02, 06:22, said:

As well as emphasising the need to restrict the opening hand on the General tab to the hand that you are providing opening constraints, I would recommend the checkbox for 'Randomly rotate generated deals 180 degrees' - this is a really useful feature: after the hands are generated, they will be rotated so that both partners are able to practise holding the specified opening hand.

Is there a way to alternate the hands (rather than randomly rotating them) for the partners -- or maybe even every N hands?
0

#5 User is offline   jonapier 

  • Pip
  • Group: Members
  • Posts: 3
  • Joined: 2015-April-05

Posted 2017-August-29, 09:15

Hi. Can someone help me by providing scripts for random Preempt and weak two hands for practicing? I see a couple that has specific for leaping Michael's, takeout, etc... But I'd like totally random if possible..
Thank you!! :D
0

#6 User is offline   cmsjw5 

  • PipPip
  • Group: Members
  • Posts: 24
  • Joined: 2011-July-09

Posted 2020-April-17, 09:10

View Postjonapier, on 2017-August-29, 09:15, said:

Hi. Can someone help me by providing scripts for random Preempt and weak two hands for practicing? I see a couple that has specific for leaping Michael's, takeout, etc... But I'd like totally random if possible..
Thank you!! :D


Yes, but this probably too late by 3 years. If not, let me know and I can write you some code.
0

#7 User is offline   pigpenz 

  • PipPipPipPipPipPipPip
  • Group: Advanced Members
  • Posts: 2,553
  • Joined: 2005-April-25

Posted 2021-February-27, 14:19

damn the constraints dealer in the old program was so nice for generating deals, none of this malarkey
0

#8 User is offline   pilowsky 

  • PipPipPipPipPipPipPip
  • Group: Advanced Members
  • Posts: 3,616
  • Joined: 2019-October-04
  • Gender:Male
  • Location:Israel

Posted 2021-February-27, 14:29

View Postpigpenz, on 2021-February-27, 14:19, said:

damn the constraints dealer in the old program was so nice for generating deals, none of this malarkey


Or, to get with the times, a load of Markle's?
0

#9 User is offline   raja1306 

  • Pip
  • Group: Members
  • Posts: 8
  • Joined: 2021-January-13
  • Gender:Male

Posted 2021-March-04, 06:51

View Postjonapier, on 2017-August-29, 09:15, said:

Hi. Can someone help me by providing scripts for random Preempt and weak two hands for practicing? I see a couple that has specific for leaping Michael's, takeout, etc... But I'd like totally random if possible..
Thank you!! :D



Hey i have created a web based tool for generating BBO LIN hands. the tool is called BLINK - You can try it here
0

#10 User is offline   pigpenz 

  • PipPipPipPipPipPipPip
  • Group: Advanced Members
  • Posts: 2,553
  • Joined: 2005-April-25

Posted 2021-March-17, 08:47

View Postpilowsky, on 2021-February-27, 14:29, said:

Or, to get with the times, a load of Markle's?

they had a good thing going the way it used to run where you could visually
see what type of hands you wanted to generate.
0

Page 1 of 1


Fast Reply

  

1 User(s) are reading this topic
0 members, 1 guests, 0 anonymous users